AYUDA con un pdf pasado a dwg

[Dalbert]

Hola buenos días el otro día pase un parcelario desde un pdf a dwg en
corel11. El caso es que ahora tengo el plano perfectamente pasado a dwg,
pero me ha pasado todas las líneas como spline y no me deja por ejemplo
hacer equidistancias de esas splines. Me dice que es "Imposible transponer
este objeto en la dirección de la vista actual". Intento explotarlo el
plano, pero aun así no consigo nada. Incluso he cargado la utilidad de
flatten, para pasarlo todo a cota 0, pero ni por esas.
Alguien conoce alguna manera de convertir esas splines en polilineas o
hacer que pueda editarlas de alguna manera.

Muchas gracias
Saludos

[Carlos L. Ayuso]

Lo puedes guardar como archivo de la 12, y las splines desaparecen, pero se
te convierten en líneas, con lo que vas a tener un montón de tramos en cada
una.
Antes de guardarlo, yo pondría a todas las splines un color, para una vez
"descojonás", con selección rápida, mpedit y pasarlas todas a polilíneas.
Puede funcionar...

Un saludo.
Carlos

Post by Dalbert
Hola buenos días el otro día pase un parcelario desde un pdf a dwg en
corel11. El caso es que ahora tengo el plano perfectamente pasado a dwg,
pero me ha pasado todas las líneas como spline y no me deja por ejemplo
hacer equidistancias de esas splines. Me dice que es "Imposible transponer
este objeto en la dirección de la vista actual". Intento explotarlo el
plano, pero aun así no consigo nada. Incluso he cargado la utilidad de
flatten, para pasarlo todo a cota 0, pero ni por esas.
Alguien conoce alguna manera de convertir esas splines en polilineas o
hacer que pueda editarlas de alguna manera.
Muchas gracias
Saludos

[david]

dalbert,

te adjunto en el mensaje el listado de un lisp que convierte splines en
polilíneas.
a mí me ha resultado bastante útil.
hay otras formas, pasando de un tipo de archivo a otro (de dwg a wmf, si no
recuerdo mal)
o como te comenta carlos, pasando por formato de versión 12

a mí la herramienta lisp me ha funcionado de lujo
la cargas, ejecutas con la orden "s2p"
y te pide el número de segmentos de polilínea en que la quieres convertir
(a mayor número de segmentos mayor precisión)

espero que te sirva
o al menos pueda hacer un apaño
a mí me ha evitado muchas horas de curro en balde!!

saludos al grupo,

david




;;CADALYST 12/03 AutoLISP Solutions SPLINE-TO-PLINE.LSP
;;(c) 2003 Tony Hotchkiss

(defun spline-to-pline (/ i)
(vl-load-com)
(setq *thisdrawing* (vla-get-activedocument
(vlax-get-acad-object)
) ;_ end of vla-get-activedocument
*modelspace* (vla-get-ModelSpace *thisdrawing*)
) ;_ end of setq
(setq spline-list (get-spline))
(setq i (- 1))
(if spline-list
(progn
(setq msg "\nNúmero de segmentos <100>: ")
(initget 6)
(setq num (getint msg))
(if (or (= num 100) (= num nil))
(setq num 100)
) ;_ end of if
(repeat (length spline-list)
(setq splobj (nth (setq i (1+ i)) spline-list))
(convert-spline splobj num)
) ;_ end of repeat
) ;_ end of progn
) ;_ end of if
) ;_ end of spline-to-pline

(defun get-spline (/ spl-list obj spline no-ent i)
(setq spl-list nil
obj nil
spline "AcDbSpline"
selsets (vla-get-selectionsets *thisdrawing*)
ss1 (vlax-make-variant "ss1")
) ;_ end of setq
(if (= (vla-get-count selsets) 0)
(setq ssobj (vla-add selsets ss1))
) ;_ end of if
(vla-clear ssobj)
(setq no-ent 1)
(while no-ent
(prompt "\nSeleccione splines: ")
(vla-Selectonscreen ssobj)
(if (> (vla-get-count ssobj) 0)
(progn
(setq no-ent nil)
(setq i (- 1))
(repeat (vla-get-count ssobj)
(setq
obj (vla-item ssobj
(vlax-make-variant (setq i (1+ i)))
) ;_ end of vla-item
) ;_ end of setq
(cond
((= (vlax-get-property obj "ObjectName") spline)
(setq spl-list
(append spl-list (list obj))
) ;_ end of setq
)
) ;_ end-of cond
) ;_ end of repeat
) ;_ end of progn
(prompt "\nNo hay entidades seleccionadas. Inténtalo de nuevo.")
) ;_ end of if
(if (and (= nil no-ent) (= nil spl-list))
(progn
(setq no-ent 1)
(prompt "\nNo hay splines seleccionadas.")
(quit)
) ;_ end of progn
) ;_ end of if
) ;_ end of while
(vla-delete (vla-item selsets 0))
spl-list
) ;_ end of get-spline

(defun convert-spline (splobj n / i)
(setq point-list nil
2Dpoint-list nil
z-list nil
spl-lyr (vlax-get-property splobj 'Layer)
startSpline (vlax-curve-getStartParam splobj)
endSpline (vlax-curve-getEndParam splobj)
i (- 1)
) ;_ end of setq
(repeat (+ n 1)
(setq i (1+ i))
(setq p (vlax-curve-getPointAtParam
splobj
(* i
(/ (- endspline startspline) n)
) ;_ end of *
) ;_ end of vlax-curve-getPointAtParam
) ;_ end of setq
(setq 2Dp (list (car p) (cadr p))
2Dpoint-list (append 2Dpoint-list 2Dp)
point-list (append point-list p)
z (caddr p)
z-list (append z-list (list z))
) ;_ end of setq
) ;_ end of repeat
(setq summ (apply '+ z-list))
(setq arraySpace
(vlax-make-safearray
vlax-vbdouble ; element type
(cons 0
(- (length point-list) 1)
) ; array dimension
) ;_ end of vlax-make-safearray
) ;_ end of setq
(setq vert-array (vlax-safearray-fill arraySpace point-list))
(vlax-make-variant vert-array)
(if (and (= :vlax-true (vlax-get-property splobj 'IsPLanar))
(= summ 0.0)
) ;_ end of and
(setq plobj (add-polyline
2Dpoint-list
vla-AddLightweightPolyline
) ;_ end of add-polyline
) ;_ end of setq
(setq plobj (add-polyline
point-list
vla-Add3DPoly
) ;_ end of add-polyline
) ;_ end of setq
) ;_ end of if
(vlax-put-property plobj 'Layer spl-lyr)
(vla-delete splobj)
(vlax-release-object splobj)
) ;_ end of convert-spline

(defun add-polyline (pt-list poly-func)
(setq arraySpace
(vlax-make-safearray
vlax-vbdouble
(cons 0
(- (length pt-list) 1)
) ; array dimension
) ;_ end of vlax-make-safearray
) ;_ end of setq
(setq vertex-array
(vlax-safearray-fill arraySpace pt-list)
) ;_ end of setq
(vlax-make-variant vertex-array)
(setq plobj (poly-func
*modelspace*
vertex-array
) ;_ end of poly-func
) ;_ end of setq
) ;_ end of add-polyline

(defun c:s2p ()
(spline-to-pline)
(princ)
) ;_ end of c:s2p

(prompt
"SPLINE-TO-PLINE by Tony Hotchkiss. Entrar S2P para iniciar"
) ;_ end of prompt

Post by Dalbert
Hola buenos días el otro día pase un parcelario desde un pdf a dwg en
corel11. El caso es que ahora tengo el plano perfectamente pasado a dwg,
pero me ha pasado todas las líneas como spline y no me deja por ejemplo
hacer equidistancias de esas splines. Me dice que es "Imposible
transponer
este objeto en la dirección de la vista actual". Intento explotarlo el
plano, pero aun así no consigo nada. Incluso he cargado la utilidad de
flatten, para pasarlo todo a cota 0, pero ni por esas.
Alguien conoce alguna manera de convertir esas splines en polilineas o
hacer que pueda editarlas de alguna manera.
Muchas gracias
Saludos

[Dalbert]

Muchas gracias a los dos, al final busque por internet un lisp que me
hiciera exactamente lo de tu archivo David. Lo conseguí de esa forma, ya
que guardandolo como la verión 12 me creaba un archivo de 1000 Mb y no era
muy manejable. Lo que había probado también es hacer un dxb del plano. La
mejor opción, en cuanto a número de líneas, fue el pasarlo a polilíneas.

Muchas gracias de nuevo
saludos